HALF ECHO LEARN / REFERENCE COLLECTION

v262.2

src/userdb/meson.build

2,009 bytesGit mode 100644Download original fileLGPL-2.1-or-later

Git blob: 3ab6ce79344dafcb0da0aec4d60d445a3f1c3977

Lines 1–49 of 49

# SPDX-License-Identifier: LGPL-2.1-or-later
 
executables += [
        libexec_template + {
                'name' : 'systemd-userwork',
                'conditions' : ['ENABLE_USERDB'],
                'sources' : files('userwork.c'),
        },
        libexec_template + {
                'name' : 'systemd-userdbd',
                'conditions' : ['ENABLE_USERDB'],
                'sources' : files(
                        'userdbd-manager.c',
                        'userdbd.c',
                ),
        },
        executable_template + {
                'name' : 'userdbctl',
                'public' : true,
                'conditions' : ['ENABLE_USERDB'],
                'sources' : files('userdbctl.c'),
        },
]
 
if conf.get('ENABLE_SSH_USERDB_CONFIG') == 1
        custom_target(
                input : '20-systemd-userdb.conf.in',
                output : '20-systemd-userdb.conf',
                command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
                install : true,
                install_dir : sshdconfdir.startswith('/usr/') ? sshdconfdir : libexecdir / 'sshd_config.d')
 
        if (not sshdconfdir.startswith(sysconfdir) or install_sysconfdir) and conf.get('LINK_SSHD_USERDB_DROPIN') == 1
                if meson.version().version_compare('>=1.3.0')
                        install_symlink(
                                '20-systemd-userdb.conf',
                                pointing_to : fs.relative_to(libexecdir / 'sshd_config.d' / '20-systemd-userdb.conf',
                                                             sshdconfdir),
                                install_dir : sshdconfdir)
                else
                        install_emptydir(sshdconfdir)
 
                        meson.add_install_script(sh, '-c',
                                ln_s.format(libexecdir / 'sshd_config.d' / '20-systemd-userdb.conf',
                                            sshdconfdir / '20-systemd-userdb.conf'))
                endif
        endif
endif