HALF ECHO LEARN / REFERENCE COLLECTION

v262.2

sysusers.d/meson.build

1,180 bytesGit mode 100644Download original fileLGPL-2.1-or-later

Git blob: 3c2e450a183bb677eb6f2c75043bd21f32b7d57d

Lines 1–30 of 30

# SPDX-License-Identifier: LGPL-2.1-or-later
 
files = [['README',                true],
         ['systemd-coredump.conf', conf.get('ENABLE_COREDUMP') == 1],
         ['systemd-oom.conf',      conf.get('ENABLE_OOMD') == 1],
         ['systemd-remote.conf',   conf.get('ENABLE_REMOTE') == 1 and conf.get('HAVE_MICROHTTPD') == 1]]
 
foreach tuple : files
        if enable_sysusers and tuple[1]
                install_data(tuple[0], install_dir : sysusersdir)
        endif
endforeach
 
in_files = [['basic.conf',            true],
            ['systemd-journal.conf',  true],
            ['systemd-network.conf',  conf.get('ENABLE_NETWORKD') == 1],
            ['systemd-resolve.conf',  conf.get('ENABLE_RESOLVE') == 1],
            ['systemd-timesync.conf', conf.get('ENABLE_TIMESYNCD') == 1],
            ['systemd-imds.conf',     conf.get('ENABLE_IMDS') == 1]]
 
foreach tuple : in_files
        file = tuple[0]
        custom_target(
                input : file + '.in',
                output: file,
                command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
                install : enable_sysusers and tuple[1],
                install_dir : sysusersdir)
endforeach